MODULE.bazel

module(name = "events-log")

bazel_dep(name = "rules_jvm_external", version = "6.10")
bazel_dep(name = "com_googlesource_gerrit_bazlets")
git_override(
    module_name = "com_googlesource_gerrit_bazlets",
    commit = "202b90383675fd8a759a865a4e0efe75de9a8932",
    remote = "https://gerrit.googlesource.com/bazlets",
)

GERRIT_API_VERS = "3.13.5"

gerrit_api_version = use_repo_rule("@com_googlesource_gerrit_bazlets//:gerrit_api_version.bzl", "gerrit_api_version")

gerrit_api_version(
    name = "gerrit_api_version",
    version = GERRIT_API_VERS,
    visibility = ["//visibility:public"],
)

maven = use_extension("@rules_jvm_external//:extensions.bzl", "maven")
maven.install(
    name = "external_plugin_deps",
    artifacts = [
        "com.google.gerrit:gerrit-plugin-api:" + GERRIT_API_VERS,
        "com.google.gerrit:gerrit-acceptance-framework:" + GERRIT_API_VERS,
    ],
)
use_repo(maven, "external_plugin_deps")

maven.install(
    name = "events-log_plugin_deps",
    artifacts = [
        "com.zaxxer:HikariCP:5.1.0",
        # Required only for tests in standalone build mode. In Gerrit tree mode,
        # this dependency is provided transitively by the acceptance framework.
        "org.bouncycastle:bcpg-jdk18on:1.83",
    ],
    duplicate_version_warning = "error",
    excluded_artifacts = [
        # Gerrit core already provides slf4j-api. Exclude it here to avoid
        # bundling duplicate classes or causing runtime version conflicts.
        "org.slf4j:slf4j-api",
    ],
    fail_if_repin_required = True,
    fail_on_missing_checksum = True,
    fetch_sources = True,
    lock_file = "//:events-log_plugin_deps.lock.json",
    repositories = [
        "https://repo1.maven.org/maven2",
    ],
    version_conflict_policy = "pinned",
)
use_repo(maven, "events-log_plugin_deps")