load("@rules_java//java:defs.bzl", "java_library")
load("@com_googlesource_gerrit_bazlets//:gerrit_plugin.bzl", "gerrit_plugin", "gerrit_plugin_tests")

gerrit_plugin(
    name = "replication",
    srcs = glob(["src/main/java/**/*.java"]),
    manifest_entries = [
        "Implementation-Title: Replication plugin",
        "Implementation-URL: https://gerrit-review.googlesource.com/#/admin/projects/plugins/replication",
        "Gerrit-PluginName: replication",
        "Gerrit-InitStep: com.googlesource.gerrit.plugins.replication.Init",
        "Gerrit-Module: com.googlesource.gerrit.plugins.replication.ReplicationModule",
        "Gerrit-SshModule: com.googlesource.gerrit.plugins.replication.SshModule",
    ],
    resources = glob(["src/main/resources/**/*"]),
    deps = [
        "//plugins/replication:replication-api",
    ],
)

gerrit_plugin(
    name = "replication-api",
    srcs = glob(
        ["src/main/java/com/googlesource/gerrit/plugins/replication/api/*.java"],
    ),
    dir_name = "replication",
    manifest_entries = [
        "Implementation-Title: Replication plugin API",
        "Implementation-URL: https://gerrit-review.googlesource.com/#/admin/projects/plugins/replication",
        "Gerrit-PluginName: replication-api",
        "Gerrit-ApiModule: com.googlesource.gerrit.plugins.replication.api.ApiModule",
    ],
)

gerrit_plugin_tests(
    name = "replication_tests",
    timeout = "long",
    srcs = glob([
        "src/test/java/**/*Test.java",
    ]),
    tags = ["replication"],
    visibility = ["//visibility:public"],
    deps = [
        ":replication__plugin",
        ":replication_util",
    ],
)

[gerrit_plugin_tests(
    name = f[:f.index(".")].replace("/", "_"),
    timeout = "long" if f.endswith("/ReplicationIT.java") else "moderate",
    srcs = [f],
    tags = ["replication"],
    visibility = ["//visibility:public"],
    deps = [
        ":replication__plugin",
        ":replication_util",
    ],
) for f in glob(["src/test/java/**/*IT.java"])]

java_library(
    name = "replication_util",
    testonly = True,
    srcs = glob(
        ["src/test/java/**/*.java"],
        exclude = ["src/test/java/**/*Test.java"],
    ),
    deps = [
        ":replication__plugin",
        "//java/com/google/gerrit/acceptance:lib",
        "//plugins:plugin-lib",
    ],
)